MODULE Out;
(* =========================================================================  
   Example GPCP .NET Console Program 
 
   Basic output library module. Useful if porting simple examples from an 
   Oberon environment.
   
   Author : Chris Burrows  
   Created: Aug 2005   
   (c) 2005-2008 CFB Software   
   http://www.cfbsoftware.com/gpcp  
   
   ========================================================================= *)

IMPORT
  Sys := "[mscorlib]System";

(* ==================================================================== *)

PROCEDURE Open*();
BEGIN
(* Do nothing *)
END Open;

(* ==================================================================== *)

PROCEDURE Char*(ch: CHAR);
BEGIN
  Sys.Console.Write(ch)
END Char;

(* ==================================================================== *)

PROCEDURE String*(s: ARRAY OF CHAR);
BEGIN
  Sys.Console.Write(MKSTR(s))
END String;

(* ==================================================================== *)

PROCEDURE Real*(r: REAL; width: INTEGER);
VAR
  s: Sys.String;
BEGIN
  s := Sys.Convert.ToString(r);
  s := s.PadLeft(width, ' ');
  Sys.Console.Write(s)
END Real;

(* ==================================================================== *)

PROCEDURE Int*(i: LONGINT; width: INTEGER);
VAR
  s: Sys.String;
BEGIN
  s := Sys.Convert.ToString(i);
  s := s.PadLeft(width, ' ');
  Sys.Console.Write(s)
END Int;

(* ==================================================================== *)

PROCEDURE Ln*;
BEGIN
  Sys.Console.WriteLine()
END Ln;

(* ==================================================================== *)

END Out.